<?xml version="1.0" ?>
<xsl:stylesheet
   version="2.0"
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   xmlns:axsl="http://www.w3.org/1999/XSL/TransformAlias">

<xsl:import href="iso_schematron_skeleton_for_saxon.xsl"/>

<xsl:template name="process-prolog">
   <axsl:output method="text" />
</xsl:template>

<!-- use default rule for process-root:  copy contens / ignore title -->
<!-- use default rule for process-pattern: ignore name and see -->
<!-- use default rule for process-name:  output name -->
<!-- use default rule for process-assert and process-report:
     call process-message -->

<xsl:template name="process-message">
   <xsl:param name="pattern"/>
   <xsl:param name="test"/>
   <xsl:param name="diagnostics" />
   <xsl:param name="id" />
   <xsl:param name="flag" />
   <xsl:param name="properties" />
   
   <!-- "Linkable" parameters -->
   <xsl:param name="role"/>
   <xsl:param name="subject"/>
   
   <!-- "Rich" parameters -->
   <xsl:param name="fpi" />
   <xsl:param name="icon" />
   <xsl:param name="lang" />
   <xsl:param name="see" />
   <xsl:param name="space" />
      <axsl:message>
         <xsl:apply-templates mode="text"/>
         <xsl:text> (</xsl:text>
         <xsl:value-of select="$pattern"/>
         <xsl:if test="$role">
            <xsl:text> / </xsl:text>
            <xsl:value-of select="$role"/>
         </xsl:if>
         <xsl:if test=" $generate-paths = 'true' or $generate-paths = 'yes' ">
            <!-- true/false is the new way -->
            <xsl:text> / </xsl:text>
            <axsl:apply-templates select="." mode="schematron-select-full-path"/>
         </xsl:if>
         <xsl:if test="string($see)">
            <xsl:text> / </xsl:text>
            <xsl:value-of select="$see"/>
         </xsl:if>
         <xsl:text>)</xsl:text>
      </axsl:message>
</xsl:template>

</xsl:stylesheet>